实验4.1 数码管及LED显示接口实验
实验箱说明部分已经介绍了数码管的控制原理，下面的程序DigitalLED.asm简单的演示了对数码管和LED控制的指令，可以在显示预设的数字和LED状态。复杂的程序可以见附盘的流水灯程序，DigitalLED2.asm
;=========================================================
;DigitalLED.asm
;实验用DSP控制实验板数码管
;DSP用I/O指令对CPLD地址1000-10005写数据，分别对应Digtal0-5
;=========================================================
.mmregs
.def main ;主程序入口
.ref Timer0Init ;Timer0初始化子程序
;数据管地址
Digital0 .set 1000H ;数据管1
Digital1 .set 1001H ;数据管2
Digital2 .set 1002H ;数据管3
Digital3 .set 1003H ;数据管4
Digital4 .set 1004H ;数据管5
Digital5 .set 1005H ;数据管6
DotPoint .set 1006H ;小数点
LED .set 1007H ;LED
STACK .usect "STACK",10H ;分配堆栈空间
.data
DATA: .word 1,2,3,4,5,6 ;测试数据
Dot_DATA: .word 010101b;
LED_DATA: .word 0101010b
.text
main:
STM #STACK+10H,SP ;设堆栈指针SP
STM #K_SWWSR,SWWSR
SSBX INTM ;关中断
LD #DATA,DP ;设数据地址DP
STM #DATA,AR1
*写数据
PORTW *AR1+,Digital0
PORTW *AR1+,Digital1
PORTW *AR1+,Digital2
PORTW *AR1+,Digital3
PORTW *AR1+,Digital4
PORTW *AR1+,Digital5
PORTW Dot_DATA,DotPoint
PORTW LED_DATA,LED
END: B END
.end
技巧提示：数码管、LED的IO地址的定义也可以单独存到一个文件中，在需要它的程序中用.include/.copy指令。
练习：修改预设值重新运行观察结果。
实验4.2 键盘接口实验
实验板上有四个按键，当有键按下时，会触发DSP的INT1中断，在INT1的中断服务程序中读入键码，判断哪一个键被按下，然后执行相应的操作。各键对应的二进制和十六进制键码分别为：
按键1： 0001B 1H
按键2： 0010B 2H
按键3： 0100B 4H
按键4： 1000B 8H
下面有一个小例子：
******************************************************
*keyboardTest.asm
*测试按键的功能，响应按键中断，读取键值，
*并对不同键按键次数计数
******************************************************
.mmregs
.global CodeStart
.global INT1_ISR
.include "../DefineIO.asm"

.data
DATA_DP:
Counter1: .word 0 ;按键1计数器
Counter2: .word 0 ;按键2计数器
Counter3: .word 0 ;按键3计数器
Counter4: .word 0 ;按键4计数器
Keyvalue: .space 30H*16 ;按键历史缓冲区
.text
CodeStart:
.copy "../SP_DP_IPTR.asm" ;初始化SP、DP和IPTR代码段
;初始化变量
STM #Keyvalue,AR2
ST #0,Counter1
ST #0,Counter2
ST #0,Counter3
ST #0,Counter4
SSBX INTM ;关中断
STM #00000010B,IMR ;允许INT1中断
STM #0FFH,IFR ;清除挂起的中断
RSBX INTM ;开中断
wait:
B wait;
*******************************************************
*键盘中断子程序
*******************************************************
INT1_ISR:
PORTR #Keyboard,*AR2 ;读取键码
ANDM #0FH,*AR2 ;Keyvalue只有低四位有效
BITF *AR2,#01H ;如果键码为1，跳转到FuncKey1
BC FuncKey1,TC
BITF *AR2,#02H ;如果键码为2，跳转到FuncKey2
BC FuncKey2,TC
BITF *AR2,#04H ;如果键码为3，跳转到FuncKey3
BC FuncKey3,TC
BITF *AR2,#08H ;如果键码为4，跳转到FuncKey4
BC FuncKey4,TC
B FuncKeyEnd ;
FuncKey1:
ADDM #1,Counter1 ;按键1计数器+1
B FuncKeyEnd
FuncKey2:
ADDM #1,Counter2 ;按键2计数器+1
B FuncKeyEnd
FuncKey3:
ADDM #1,Counter3 ;按键3计数器+1
B FuncKeyEnd
FuncKey4:
ADDM #1,Counter4 ;按键4计数器+1
B FuncKeyEnd
FuncKeyEnd:
PORTW *AR2+,Digital0 ;当前键码显示到数码管上
STM #0FFH,IFR ;清除挂起的中断
RETE