很多年前用51的汇编语言写过, 看用不用的上.

;**********************************************
;  subroutine:
;        name:        Convert_Hex2EMcode
;        function:
;                convert hex data to em code
;        input:
;                gvUserBuf
;        output:
;                gvBuffer
;**********************************************
Convert_Hex2EMcode:
                mov        gvBuffer,#0ffh
                mov        r0,#gvBuffer+1
                mov        @r0,#01h
                mov        r1,#gvUserBuf
                mov        a,@r1
                mov        b,a
                mov        bitcount,#07h
                mov        bytecount,#05h
                mov        r4,#04h
ConvertEMcode_Loop1:
                mov        a,b
                rlc        a
                mov        b,a
                mov        a,@r0
                rlc        a
                mov        @r0,a
                djnz        bitcount,ConvertEMcode_Loop11
                mov        bitcount,#08h
                inc        r0
ConvertEMcode_Loop11:
                djnz        r4,ConvertEMcode_Loop1
                mov        a,@r1
                anl        a,#0f0h
                swap        a
                mov        c,PSW.0
                mov        a,@r0
                rlc        a
                mov        @r0,a
                djnz        bitcount,ConvertEMcode_Loop12
                mov        bitcount,#08h
                inc        r0
ConvertEMcode_Loop12:
                mov        r4,#04h
ConvertEMcode_Loop2:
                mov        a,b
                rlc        a
                mov        b,a
                mov        a,@r0
                rlc        a
                mov        @r0,a
                djnz        bitcount,ConvertEMcode_Loop21
                mov        bitcount,#08h
                inc        r0
ConvertEMcode_Loop21:
                djnz        r4,ConvertEMcode_Loop2
                mov        a,@r1
                anl        a,#0fh
                mov        c,PSW.0
                mov        a,@r0
                rlc        a
                mov        @r0,a
                djnz        bitcount,ConvertEMcode_Loop22
                mov        bitcount,#08h
                inc        r0
ConvertEMcode_Loop22:
                inc        r1
                mov        a,@r1
                mov        b,a
                mov        r4,#04h
                djnz        bytecount,ConvertEMcode_Loop1
                mov        a,gvBuffer+7
                swap        a
                rlc        a
                mov        gvBuffer+7,a
ConvertEMcode_Loop3:
                mov        r1,#gvUserBuf
                mov        r3,#00h
                mov        r5,#05h
ConvertEMcode_Loop31:
                mov        a,@r1
                swap        a
                anl        a,#0fh
                xrl        a,r3
                mov        r3,a
                mov        a,@r1
                anl        a,#0fh
                xrl        a,r3
                mov        r3,a
                inc        r1
                djnz        r5,ConvertEMcode_Loop31                ; get colume parity
                clr        c                                ; last bit is zero
                mov        a,r3
                rlc        a
                mov        r3,a                                ; get last parity
                mov        a,@r0
                anl        a,#11100000b
                orl        a,r3
                mov        @r0,a
                ret