;这是一个独立控制三路PWM的汇编程序：
;三个输出口以低电平为有效输出，也就是当输出0％时为高电平输出，输出100％时为低电平输出。改变10H-12H的值可以控制三路PWM的占空比变化，例如当10H中的值从0-255变化时候，P1.0输出从0％-100％变化
;此程序中频率完全固定不变化，改变10H，11H，12H中的值仅改变三路输出的占空比，频率是完全恒定的，要改变频率，请自行改变定时器中断的值。这里的PWM波周期为 50us x 255＝12750us，频率约为78Hz
DENG1 EQU P1.0  ;红灯输出口
DENG2 EQU P1.1  ;绿灯输出口
DENG3 EQU P1.2  ;蓝灯输出口
ld1 EQU 10H     ;红灯亮度,即占空比的比值,0-255变化
ld2 EQU 11H     ;绿灯亮度,即占空比的比值,0-255变化
ld3 EQU 12H     ;蓝灯亮度,即占空比的比值,0-255变化

    ORG 0000H
    LJMP mm
    ORG 000BH
    LJMP t000

mm:                    ;复位程序
MOV SP,#60H
MOV P1,#0FFH    ;p1置高,关闭全部灯
MOV ld1,#10H     ;给红灯赋值10,这里是作为测试随便给的一个数值,10h亮度很低
MOV ld2,#0FFH    ;给绿灯赋值FF,这里是作为测试随便给的一个数值,ffh则P1.1输出低电平,控制占空比100％,灯全亮
MOV ld3,#00H     ;给蓝灯赋值FF,这里是作为测试随便给的一个数值,00h亮度为0,就是熄灭
MOV TMOD,#01H   ;50us t0中断设置
MOV TH0,#0FFH
MOV TL0,#0CEH
SETB EA
SETB ET0
SETB TR0
sJMP $

t000:                      ;50us t0中断子程序，用于实现三路PWM输出
PUSH ACC
PUSH PSW
MOV TH0,#0FFH
MOV TL0,#0CEH
CJNE R0,#00H,AA  ;从这里是程序的精华,检测R0值是否为0(或者说是否已经被减为0),等于0则下一条重新赋值255,否则跳到AA
MOV R0,#255       ;R0赋值255
MOV R1,ld1           ;把红灯亮度值复制给R1
MOV R2,ld2           ;把绿灯亮度值复制给R2
MOV R3,ld3           ;把蓝灯亮度值复制给R3
AA:CJNE R1,#00H,BB  ;判断控制红灯的值是否(或是否被减为0)为0,是则下一条关闭红灯,否则跳到BB
SETB DENG1          ;关闭红灯
sJMP CC                 ;跳到CC检测绿灯
BB:CLR DENG1       ;打开(或继续打开)红灯
DEC R1                 ;R1数值减1
CC:CJNE R2,#00H,DD  ;这里控制绿灯与上面红灯原理一样
SETB DENG2
sJMP EE
DD:CLR DENG2
DEC R2
EE:CJNE R3,#00H,FF   ;这里控制蓝灯与上面的原理一样
SETB DENG3
sJMP GG
FF:CLR DENG3
DEC R3
GG:dEC R0              ;把R0的值减1，(R0的初始值是255)
POP PSW
POP ACC
RETI

END