51单片机

N字节无符号二进制 转 十进制BCD码（C调用汇编子程序）

2020-02-01 16:23发布

站内问答 / 51单片机
5359 17 17
汇编子程序模块：NBYTE_BCD.asm
  1. ;========================================================================
  2. ; extern void NBYTEBCD(unsigned char idata *pri, unsigned char leni, unsigned char idata *pro, unsigned char leno);
  3. ;
  4. ; N字节无符号二进制  对应  十进制BCD码字节数
  5. ; (N <= 4 )  则 N+1   
  6. ; (N <= 9 )  则 N+2          
  7. ; (N <= 12) 则 N+3
  8. ; ……

  10. $NOMOD51

  12. NAME NBYTE_BCD                                                  ;模块名

  14. ?PR?_NBYTEBCD?NBYTE_BCD  SEGMENT CODE              ;在程序存储区中定义段     
  15. ?DT?_NBYTEBCD?NBYTE_BCD  SEGMENT DATA OVERLAYABLE
  16.         PUBLIC  ?_NBYTEBCD?BYTE
  17.         PUBLIC  _NBYTEBCD                                        ;用PUBLIC 声明函数为公共函数

  19.         RSEG          ?DT?_NBYTEBCD?NBYTE_BCD
  20. ?_NBYTEBCD?BYTE:
  21.             pri?040:   DS   1    ;R7
  22.            leni?041:   DS   1    ;R5
  23.             pro?042:   DS   1    ;R3
  24.            ORG 3
  25.            leno?043:   DS   1
  26.         RSEG    ?PR?_NBYTEBCD?NBYTE_BCD                ;用RSEG 表示函数可被连接器放置在任何地方

  28. ;========================================================================
  29. ;函数：N字节无符号二进制转十进制BCD码
  30. ;输入：*pri         
  31. ;输出：*pro
  32. ;资源：ACC、CY、R0、R1、R3、R4、R5、R7、leno?043
  33. ; ROM：59B（包括调用函数时的形参输入）

  35. _NBYTEBCD:
  36.         ;USING        0
  37.         MOV  A,R7
  38.         ADD  A,R5  
  39.         DEC  A     
  40.         MOV  R7,A
  41.        
  42.         MOV  A,leno?043
  43.         MOV  R4,A
  44.         ADD  A,R3
  45.         DEC  A      
  46.         MOV  R3,A

  48.         MOV  R0,A
  49. NP__0:
  50.          MOV  @R0,#0
  51.         DEC  R0
  52.         DJNZ R4,NP__0
  53.        
  54.         MOV  A,R5       ;转换(R5)字节二进制整数
  55.         RL   A
  56.         RL   A
  57.         RL   A
  58.         MOV  R1,A       ;计数器
  59.      CLR  C
  60. NP__1:       
  61.         MOV  A,R5
  62.         MOV  R4,A       ;循环(R5)次
  63.         MOV  A,R7
  64.         MOV  R0,A
  65. NP__2:
  66.          MOV  A,@R0      ;从高端移出待转换数的1位到CY中
  67.          RLC  A
  68.          MOV  @R0,A
  69.         DEC  R0
  70.         DJNZ R4,NP__2
  71.        
  72.         MOV  A,leno?043
  73.         MOV  R4,A       ;循环(leno)次
  74.         MOV  A,R3
  75.         MOV  R0,A
  76. NP__3:
  77.          MOV  A,@R0      ;BCD码带进位自身相加，相当于乘2
  78.          ADDC A,@R0
  79.          DA   A          ;十进制调整
  80.          MOV  @R0,A
  81.         DEC  R0
  82.         DJNZ R4,NP__3
  83.        
  84.          DJNZ R1,NP__1
  85.        
  86.          RET

  88.         END
复制代码使用方法，将 NBYTE_BCD.asm 添加到工程中，在 main.c 中声明后就可以调用，举例：
  1. unsigned char asc[8] = {0x0A,0xAA,0xAA,0xAA,0xAA,0xAA,0xAA,0xAA};
  2. unsigned char nz[10];

  4. extern void NBYTEBCD(unsigned char idata *pri, unsigned char leni, unsigned char idata *pro, unsigned char leno);

  6. void main(void)
  7. {
  8.         NBYTEBCD(asc, 8, nz, 10);
  9.        
  10.         while (1)
  11.         {
  12.                
  13.         }
  14. }
复制代码
友情提示: 此问题已得到解决，问题已经关闭,关闭后问题禁止继续编辑，回答。
17条回答
BXAK
2020-02-03 02:21
本帖最后由 BXAK 于 2012-9-29 15:28 编辑
downtoearth 发表于 2012-9-29 14:28
BCD码不是用4位的二进制数表示1位的十进制数中的0-9吗？那么一个8位二进制数就是只可以表示0-99咯！
那为什 ...


1字节（即8位）无符号二进制数：0000 0000 ~ 1111 1111         
对应 十六进制：0x00 ~ 0xFF   
对应    十进制：0 ~ 255

比如想把十六进制数以十进制显示到数码管、液晶屏……时，
如果小于等于4字节时直接用除法和求余提取就可以，如：
unsigned int n = 12345;
十万位 = n/10000;
万位 = n/1000%10;
……
但如果8字节、……的十六进制数时，上面的方法行不通（keil C51支持最大的整形数据是unsigned long，4字节），这就需要把 8字节、……的十六进制数 先转成BCD


之所以弄这个程序是因为想做等精度频率计，需要公式 fx = (fo * nx) / no，其中:
unsigned long code fo = 22118400UL;
unsigned long no,nx;
运算中为了精确没有用浮点float运算，keil C51不支持double。
(fo * nx) 的积是 8字节十六进制，
(fo * nx) / no 的商是 8字节十六进制，余数是 4字节十六进制

一周热门 更多>