51单片机

帮我分析一下程序，谢谢！

2019-07-15 10:21发布

站内问答 / 51单片机
5862 3 1015
才开始学汇编语言，不是很懂。大神们帮我分析一下这个程序，能配合流程图讲解最好。谢谢大佬们了。
  1. COUNT                                        EQU 30H                        ;T0中断计数
  2. SNLEDDATA                        EQU 31H                        ;存储南北数码管显示的数据
  3. SNCOLORFLAG                        EQU 32H                ;=1时南北绿灯亮，=2时南北黄灯亮，=3时南北红灯亮
  4. SNLEDDATAINIT        EQU 33H                        ;存储南北各颜 {MOD}灯的初始时间
  5. EWLEDDATA                        EQU 34H                        ;存储东西数码管显示的数据
  6. EWCOLORFLAG                        EQU 35H                ;=1时东西红灯亮，=2时东西绿灯亮，=3时东西黄灯亮
  7. EWLEDDATAINIT        EQU 36H                        ;存储东西各颜 {MOD}灯的初始时间
  8.                         org 0000h
  9.                         lJMP MAIN
  10.                         org 0003h
  11.                         lJMP INT00
  12.                         org 000Bh
  13.                         lJMP T00
  14.                         org 0100h
  15. ;主函数***************************************                               
  16. MAIN:            MOV SP,#60H
  17.                         MOV TMOD,#01H
  18.                         MOV TH0,#0eCH
  19.                         MOV TL0,#078H
  20.                         MOV COUNT,#00H       
  21.                         SETB TR0                                                                                    ;开定时器0
  22.                         SETB ET0                                                                                        ;允许定时器0中断
  23.                         SETB EX0                                                                                        ;允许外部0中断                                                                                     
  24.                         SETB EA                                                                                                ;开总中断
  25.                         MOV SNLEDDATAINIT,#15
  26.                         MOV EWLEDDATAINIT,#18
  27.                         MOV SNLEDDATA,SNLEDDATAINIT
  28.                         MOV EWLEDDATA,EWLEDDATAINIT       
  29.                         MOV P2,#0feH                       
  30.                         MOV SNCOLORFLAG,#01       
  31.                         MOV EWCOLORFLAG,#01                                                                                                     
  32. ;初始化结束***********************************
  33. START:               
  34.                         MOV A,COUNT
  35.                         CJNE A,#200,NOT1S        ;没到1秒跳转
  36.                         MOV COUNT,#00                        ;1秒时间到                       
  37.                         DEC SNLEDDATA
  38.                         MOV A,SNLEDDATA
  39.                         JNZ        checkewleddata
  40.                         MOV SNLEDDATA,SNLEDDATAINIT
  41.                         INC SNCOLORFLAG
  42.                         MOV A,SNCOLORFLAG
  43.                         CJNE A,#04,checkewleddata
  44.                         MOV SNCOLORFLAG,#01
  45. checkewleddata:
  46.                         DEC EWLEDDATA                                               
  47.                         MOV A,EWLEDDATA
  48.                         JNZ        NOT1S
  49.                         MOV EWLEDDATA,EWLEDDATAINIT
  50.                         INC EWCOLORFLAG
  51.                         MOV A,EWCOLORFLAG
  52.                         CJNE A,#04,NOT1S
  53.                         MOV EWCOLORFLAG,#01                       
  54. NOT1S:                       
  55.                         LCALL snCOLORCHECK
  56.                         LCALL ewCOLORCHECK
  57.                         LCALL DISPLAY       
  58.                         SJMP START
  59. ;****************************************
  60. ;南北红绿黄灯控制**************************
  61. snCOLORCHECK:
  62.                         PUSH ACC
  63.                         PUSH B
  64.                         PUSH PSW                       
  65. sngreen:
  66.                         MOV A,SNCOLORFLAG
  67.                         CJNE A,#01,snYELLOW
  68.                         MOV SNLEDDATAINIT,#03                                        ;设置南北黄灯闪烁时间
  69.                         CLR P1.2
  70.                         CLR P1.1
  71.                         SETB P1.0                                        ;南北绿灯亮                                                                               
  72.                         SETB P1.7
  73.                         CLR  P1.6
  74.                         JMP snCOLORCHECKOUT
  75. snYELLOW:
  76.                         MOV A,SNCOLORFLAG
  77.                         CJNE A,#02,snred
  78.                         MOV SNLEDDATAINIT,#18                                        ;设置南北红灯亮时间
  79.                         MOV A,COUNT
  80.                         MOV B,#50
  81.                         DIV AB
  82.                         MOV A,B
  83.                         CJNE A,#00H,snNOTFLASH
  84.                         CPL P1.1                                                                ;南北黄灯闪烁       
  85.                         CLR P1.0
  86.                         CLR P1.2
  87.                                
  88. snNOTFLASH:
  89.                         JMP snCOLORCHECKOUT
  90. snred:
  91.                         MOV SNLEDDATAINIT,#15                                                ;设置南北绿灯亮时间
  92.                         CLR P1.0
  93.                         CLR P1.1
  94.                         SETB P1.2                                            ;南北红灯亮                                                                                       
  95.                         SETB P1.6
  96.                         CLR  P1.7
  97. snCOLORCHECKOUT:
  98.                         POP PSW
  99.                         POP B
  100.                         POP ACC
  101.                         RET
  102. ;******************************************************
  103. ;东西红绿黄灯控制**************************************                       
  104. ewCOLORCHECK:
  105.                         PUSH ACC
  106.                         PUSH B
  107.                         PUSH PSW
  108. ewred:
  109.                         MOV A,ewCOLORFLAG
  110.                         CJNE A,#01,ewyellow
  111.                         MOV ewLEDDATAINIT,#15                                        ;设置东西绿灯亮时间
  112.                         CLR P1.3
  113.                         CLR P1.4
  114.                         SETB P1.5                                                                                        ;东西红灯亮
  115.                         JMP ewCOLORCHECKOUT
  116. ewyellow:
  117.                         MOV A,ewCOLORFLAG
  118.                         CJNE A,#03,ewgreen
  119.                         MOV ewLEDDATAINIT,#18                                        ;设置东西红灯亮时间
  120.                         MOV A,COUNT
  121.                         MOV B,#50
  122.                         DIV AB
  123.                         MOV A,B
  124.                         CJNE A,#00H,ewNOTFLASH
  125.                         CPL P1.4                                                                                        ;东西黄灯闪烁
  126.                         CLR P1.3
  127.                         CLR P1.5

  129. ewNOTFLASH:
  130.                         JMP ewCOLORCHECKOUT
  131. ewgreen:
  132.                         MOV ewLEDDATAINIT,#03                                                ;设置东西黄灯闪烁时间
  133.                         CLR P1.4
  134.                         CLR P1.5
  135.                         SETB P1.3                                                                                        ;东西绿灯亮
  136. ewCOLORCHECKOUT:
  137.                         POP PSW
  138.                         POP B
  139.                         POP ACC
  140.                         RET
  141. ;************************************************************
  142. ;数码管显示**************************************************
  143. DISPLAY:
  144.                         PUSH ACC
  145.                         PUSH PSW
  146.                         PUSH B
  147.                         MOV A,SNLEDDATA
  148.                         MOV B,#10
  149.                         DIV AB
  150.                         MOV R0,B
  151.                         MOV R1,A
  152.                         MOV A,EWLEDDATA
  153.                         MOV B,#10
  154.                         DIV AB
  155.                         MOV R2,B
  156.                         MOV R3,A
  157.                         MOV DPTR,#TABLE
  158.                         MOV A,P2
  159. DISPSNH:
  160.                         CJNE A,#0feH,DISPSNL
  161.                         MOV A,R1
  162.                         MOVC A,@A+DPTR
  163.                         MOV P0,A
  164.                         JMP DISPOUT       
  165. DISPSNL:
  166.                         CJNE A,#0fdH,DISPEWH
  167.                         MOV A,R0
  168.                         MOVC A,@A+DPTR
  169.                         MOV P0,A
  170.                         JMP DISPOUT                       
  171. DISPEWH:
  172.                         CJNE A,#0fbH,DISPEWL
  173.                         MOV A,R3
  174.                         MOVC A,@A+DPTR
  175.                         MOV P0,A
  176.                         JMP DISPOUT
  177. DISPEWL:
  178.                         CJNE A,#0f7H,DISPOUT
  179.                         MOV A,R2
  180.                         MOVC A,@A+DPTR
  181.                         MOV P0,A
  182. DISPOUT:                                               
  183.                         POP B
  184.                         POP PSW
  185.                         POP ACC
  186.                         RET               
  187. ;*****************************************                       
  188. TABLE:DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH
  189.           ;   0   1   2   3   4   5   6   7   8   9
  190. ;T0中断函数*******************************                               
  191. T00:        PUSH ACC
  192.                         PUSH PSW
  193.                         MOV TH0,#0ecH                  
  194.                         MOV TL0,#078H                                       
  195.                         MOV A,P2
  196.                         RL A
  197.                         CJNE A,#11101111B,NOT5                                               
  198.                         MOV A,#0feH                                                                        ;p2.0=0,南北数码管十位亮，p2.1=0,南北数码管个位亮
  199. NOT5:           MOV P2,A                                                                        ;p2.2=0,东西数码管十位亮，p2.3=0,东西数码管个位亮
  200.                         INC COUNT       
  201.                         POP PSW
  202.                         POP ACC
  203.                         REti

  205. ;外部中断0***********************************
  206. INT00:           push acc
  207.                         push psw
  208.                         mov a,p0
  209.                         push acc
  210.                     mov a,p1
  211.                         push acc
  212.                         mov a,p2
  213.                         push acc
  214. INT10:                jnb  p3.6,INT11
  215.                         jnb  p3.7,INT12
  216.                         SJMP  INT13
  217. INT11:                LCALL  INT01
  218.                         SJMP  INT13
  219. INT12:                LCALL  INT02               
  220. INT13:                mov p1,#0C0h
  221.                         mov p2,#0ffh
  222.                         jnb p3.2,INT10
  223.                         pop acc
  224.                         mov p2,a
  225.                         pop acc
  226.                         mov p1,a
  227.                         pop acc
  228.                         mov p0,a
  229.                         pop psw
  230.                         pop acc
  231.                         reti
  232. INT01:            mov p2,#0ffh
  233.                         mov p1,#01001100B
  234.                         jnb p3.6,$               
  235.                         ret       
  236. INT02:            mov p2,#0ffh
  237.                     mov p1,#10100001B               
  238.                     jnb p3.7,$       
  239.                         ret
  240.                        
  241. ;*****************************************


  244.                         END
复制代码
友情提示: 此问题已得到解决，问题已经关闭,关闭后问题禁止继续编辑，回答。
3条回答
人中狼
2019-07-15 15:49
画流程图也很废精力的，其实你可以试试自己画，这样也更容易理解程序流程

一周热门 更多>